ecoin-qt.pro 13 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428
  1. # ECOin - Copyright (c) - 2014/2021 - GPLv3 - epsylon@riseup.net (https://03c8.net)
  2. TEMPLATE = app
  3. TARGET = ecoin-qt
  4. VERSION = 0.0.2
  5. INCLUDEPATH += src src/json src/qt
  6. DEFINES += QT_GUI BOOST_THREAD_USE_LIB BOOST_SPIRIT_THREADSAFE
  7. CONFIG += no_include_pwd
  8. CONFIG += thread
  9. OBJECTS_DIR = build
  10. MOC_DIR = build
  11. UI_DIR = build
  12. # use: qmake "RELEASE=1"
  13. contains(RELEASE, 1) {
  14. # Mac: compile for maximum compatibility (10.5, 32-bit)
  15. macx:QMAKE_CXXFLAGS += -mmacosx-version-min=10.5 -arch x86_64 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  16. !windows:!macx {
  17. # Linux: static link
  18. LIBS += -Wl,-Bstatic
  19. }
  20. }
  21. !win32 {
  22. # for extra security against potential buffer overflows: enable GCCs Stack Smashing Protection
  23. QMAKE_CXXFLAGS *= -fstack-protector-all --param ssp-buffer-size=1
  24. QMAKE_LFLAGS *= -fstack-protector-all --param ssp-buffer-size=1
  25. # We need to exclude this for Windows cross compile with MinGW 4.2.x, as it will result in a non-working executable!
  26. # This can be enabled for Windows, when we switch to MinGW >= 4.4.x.
  27. }
  28. # for extra security on Windows: enable ASLR and DEP via GCC linker flags
  29. win32:QMAKE_LFLAGS *= -Wl,--dynamicbase -Wl,--nxcompat
  30. win32:QMAKE_LFLAGS += -static-libgcc -static-libstdc++
  31. # use: qmake "USE_QRCODE=1"
  32. # libqrencode (http://fukuchi.org/works/qrencode/index.en.html) must be installed for support
  33. contains(USE_QRCODE, 1) {
  34. message(Building with QRCode support)
  35. DEFINES += USE_QRCODE
  36. LIBS += -lqrencode
  37. }
  38. # use: qmake "USE_UPNP=1" ( enabled by default; default)
  39. # or: qmake "USE_UPNP=0" (disabled by default)
  40. # or: qmake "USE_UPNP=-" (not supported)
  41. # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  42. contains(USE_UPNP, -) {
  43. message(Building without UPNP support)
  44. } else {
  45. message(Building with UPNP support)
  46. count(USE_UPNP, 0) {
  47. USE_UPNP=1
  48. }
  49. DEFINES += USE_UPNP=$$USE_UPNP STATICLIB
  50. INCLUDEPATH += $$MINIUPNPC_INCLUDE_PATH
  51. LIBS += $$join(MINIUPNPC_LIB_PATH,,-L,) -lminiupnpc
  52. win32:LIBS += -liphlpapi
  53. }
  54. # use: qmake "USE_DBUS=1"
  55. contains(USE_DBUS, 1) {
  56. message(Building with DBUS (Freedesktop notifications) support)
  57. DEFINES += USE_DBUS
  58. QT += dbus
  59. }
  60. # use: qmake "USE_IPV6=1" ( enabled by default; default)
  61. # or: qmake "USE_IPV6=0" (disabled by default)
  62. # or: qmake "USE_IPV6=-" (not supported)
  63. contains(USE_IPV6, -) {
  64. message(Building without IPv6 support)
  65. } else {
  66. count(USE_IPV6, 0) {
  67. USE_IPV6=1
  68. }
  69. DEFINES += USE_IPV6=$$USE_IPV6
  70. }
  71. contains(ECOIN_NEED_QT_PLUGINS, 1) {
  72. DEFINES += ECOIN_NEED_QT_PLUGINS
  73. QTPLUGIN += qcncodecs qjpcodecs qtwcodecs qkrcodecs qtaccessiblewidgets
  74. }
  75. INCLUDEPATH += src/leveldb/include src/leveldb/helpers
  76. LIBS += $$PWD/src/leveldb/libleveldb.a $$PWD/src/leveldb/libmemenv.a
  77. SOURCES += src/txdb-leveldb.cpp
  78. !win32 {
  79. # we use QMAKE_CXXFLAGS_RELEASE even without RELEASE=1 because we use RELEASE to indicate linking preferences not -O preferences
  80. genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a
  81. } else {
  82. # make an educated guess about what the ranlib command is called
  83. isEmpty(QMAKE_RANLIB) {
  84. QMAKE_RANLIB = $$replace(QMAKE_STRIP, strip, ranlib)
  85. }
  86. LIBS += -lshlwapi
  87. genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX TARGET_OS=OS_WINDOWS_CROSSCOMPILE $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libleveldb.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libmemenv.a
  88. }
  89. genleveldb.target = $$PWD/src/leveldb/libleveldb.a
  90. genleveldb.depends = FORCE
  91. PRE_TARGETDEPS += $$PWD/src/leveldb/libleveldb.a
  92. QMAKE_EXTRA_TARGETS += genleveldb
  93. # Gross ugly hack that depends on qmake internals, unfortunately there is no other way to do it.
  94. QMAKE_CLEAN += $$PWD/src/leveldb/libleveldb.a; cd $$PWD/src/leveldb ; $(MAKE) clean
  95. # regenerate src/build.h
  96. !windows|contains(USE_BUILD_INFO, 1) {
  97. genbuild.depends = FORCE
  98. genbuild.commands = cd $$PWD; /bin/sh share/genbuild.sh $$OUT_PWD/build/build.h
  99. genbuild.target = $$OUT_PWD/build/build.h
  100. PRE_TARGETDEPS += $$OUT_PWD/build/build.h
  101. QMAKE_EXTRA_TARGETS += genbuild
  102. DEFINES += HAVE_BUILD_INFO
  103. }
  104. contains(USE_O3, 1) {
  105. message(Building O3 optimization flag)
  106. QMAKE_CXXFLAGS_RELEASE -= -O2
  107. QMAKE_CFLAGS_RELEASE -= -O2
  108. QMAKE_CXXFLAGS += -O3
  109. QMAKE_CFLAGS += -O3
  110. }
  111. *-g++-32 {
  112. message("32 platform, adding -msse2 flag")
  113. QMAKE_CXXFLAGS += -msse2
  114. QMAKE_CFLAGS += -msse2
  115. }
  116. QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wextra -Wno-ignored-qualifiers -Wformat -Wformat-security -Wno-unused-parameter -Wstack-protector
  117. # Input
  118. DEPENDPATH += src src/json src/qt
  119. HEADERS += src/qt/ecoingui.h \
  120. src/qt/transactiontablemodel.h \
  121. src/qt/addresstablemodel.h \
  122. src/qt/optionsdialog.h \
  123. src/qt/coincontroldialog.h \
  124. src/qt/coincontroltreewidget.h \
  125. src/qt/sendcoinsdialog.h \
  126. src/qt/addressbookpage.h \
  127. src/qt/signverifymessagedialog.h \
  128. src/qt/aboutdialog.h \
  129. src/qt/editaddressdialog.h \
  130. src/qt/ecoinaddressvalidator.h \
  131. src/alert.h \
  132. src/addrman.h \
  133. src/base58.h \
  134. src/bignum.h \
  135. src/checkpoints.h \
  136. src/compat.h \
  137. src/coincontrol.h \
  138. src/sync.h \
  139. src/util.h \
  140. src/uint256.h \
  141. src/kernel.h \
  142. src/scrypt.h \
  143. src/pbkdf2.h \
  144. src/zerocoin/Accumulator.h \
  145. src/zerocoin/AccumulatorProofOfKnowledge.h \
  146. src/zerocoin/Coin.h \
  147. src/zerocoin/CoinSpend.h \
  148. src/zerocoin/Commitment.h \
  149. src/zerocoin/ParamGeneration.h \
  150. src/zerocoin/Params.h \
  151. src/zerocoin/SerialNumberSignatureOfKnowledge.h \
  152. src/zerocoin/SpendMetaData.h \
  153. src/zerocoin/ZeroTest.h \
  154. src/zerocoin/Zerocoin.h \
  155. src/serialize.h \
  156. src/strlcpy.h \
  157. src/main.h \
  158. src/miner.h \
  159. src/net.h \
  160. src/key.h \
  161. src/db.h \
  162. src/txdb.h \
  163. src/walletdb.h \
  164. src/script.h \
  165. src/init.h \
  166. src/irc.h \
  167. src/mruset.h \
  168. src/json/json_spirit_writer_template.h \
  169. src/json/json_spirit_writer.h \
  170. src/json/json_spirit_value.h \
  171. src/json/json_spirit_utils.h \
  172. src/json/json_spirit_stream_reader.h \
  173. src/json/json_spirit_reader_template.h \
  174. src/json/json_spirit_reader.h \
  175. src/json/json_spirit_error_position.h \
  176. src/json/json_spirit.h \
  177. src/qt/clientmodel.h \
  178. src/qt/guiutil.h \
  179. src/qt/transactionrecord.h \
  180. src/qt/guiconstants.h \
  181. src/qt/optionsmodel.h \
  182. src/qt/monitoreddatamapper.h \
  183. src/qt/transactiondesc.h \
  184. src/qt/transactiondescdialog.h \
  185. src/qt/ecoinamountfield.h \
  186. src/wallet.h \
  187. src/keystore.h \
  188. src/qt/transactionfilterproxy.h \
  189. src/qt/transactionview.h \
  190. src/qt/walletmodel.h \
  191. src/ecoinrpc.h \
  192. src/qt/overviewpage.h \
  193. src/qt/csvmodelwriter.h \
  194. src/crypter.h \
  195. src/qt/sendcoinsentry.h \
  196. src/qt/qvalidatedlineedit.h \
  197. src/qt/ecoinunits.h \
  198. src/qt/qvaluecombobox.h \
  199. src/qt/askpassphrasedialog.h \
  200. src/protocol.h \
  201. src/qt/notificator.h \
  202. src/qt/qtipcserver.h \
  203. src/allocators.h \
  204. src/ui_interface.h \
  205. src/qt/rpcconsole.h \
  206. src/version.h \
  207. src/netbase.h \
  208. src/clientversion.h
  209. SOURCES += src/qt/ecoin.cpp src/qt/ecoingui.cpp \
  210. src/qt/transactiontablemodel.cpp \
  211. src/qt/addresstablemodel.cpp \
  212. src/qt/optionsdialog.cpp \
  213. src/qt/sendcoinsdialog.cpp \
  214. src/qt/coincontroldialog.cpp \
  215. src/qt/coincontroltreewidget.cpp \
  216. src/qt/addressbookpage.cpp \
  217. src/qt/signverifymessagedialog.cpp \
  218. src/qt/aboutdialog.cpp \
  219. src/qt/editaddressdialog.cpp \
  220. src/qt/ecoinaddressvalidator.cpp \
  221. src/alert.cpp \
  222. src/version.cpp \
  223. src/sync.cpp \
  224. src/util.cpp \
  225. src/netbase.cpp \
  226. src/key.cpp \
  227. src/script.cpp \
  228. src/main.cpp \
  229. src/miner.cpp \
  230. src/init.cpp \
  231. src/net.cpp \
  232. src/irc.cpp \
  233. src/checkpoints.cpp \
  234. src/addrman.cpp \
  235. src/db.cpp \
  236. src/walletdb.cpp \
  237. src/qt/clientmodel.cpp \
  238. src/qt/guiutil.cpp \
  239. src/qt/transactionrecord.cpp \
  240. src/qt/optionsmodel.cpp \
  241. src/qt/monitoreddatamapper.cpp \
  242. src/qt/transactiondesc.cpp \
  243. src/qt/transactiondescdialog.cpp \
  244. src/qt/ecoinstrings.cpp \
  245. src/qt/ecoinamountfield.cpp \
  246. src/wallet.cpp \
  247. src/keystore.cpp \
  248. src/qt/transactionfilterproxy.cpp \
  249. src/qt/transactionview.cpp \
  250. src/qt/walletmodel.cpp \
  251. src/ecoinrpc.cpp \
  252. src/rpcdump.cpp \
  253. src/rpcnet.cpp \
  254. src/rpcmining.cpp \
  255. src/rpcwallet.cpp \
  256. src/rpcblockchain.cpp \
  257. src/rpcrawtransaction.cpp \
  258. src/qt/overviewpage.cpp \
  259. src/qt/csvmodelwriter.cpp \
  260. src/crypter.cpp \
  261. src/qt/sendcoinsentry.cpp \
  262. src/qt/qvalidatedlineedit.cpp \
  263. src/qt/ecoinunits.cpp \
  264. src/qt/qvaluecombobox.cpp \
  265. src/qt/askpassphrasedialog.cpp \
  266. src/protocol.cpp \
  267. src/qt/notificator.cpp \
  268. src/qt/qtipcserver.cpp \
  269. src/qt/rpcconsole.cpp \
  270. src/noui.cpp \
  271. src/kernel.cpp \
  272. src/scrypt-arm.S \
  273. src/scrypt-x86.S \
  274. src/scrypt-x86_64.S \
  275. src/scrypt.cpp \
  276. src/pbkdf2.cpp \
  277. src/zerocoin/Accumulator.cpp \
  278. src/zerocoin/AccumulatorProofOfKnowledge.cpp \
  279. src/zerocoin/Coin.cpp \
  280. src/zerocoin/CoinSpend.cpp \
  281. src/zerocoin/Commitment.cpp \
  282. src/zerocoin/ParamGeneration.cpp \
  283. src/zerocoin/Params.cpp \
  284. src/zerocoin/SerialNumberSignatureOfKnowledge.cpp \
  285. src/zerocoin/SpendMetaData.cpp \
  286. src/zerocoin/ZeroTest.cpp
  287. RESOURCES += \
  288. src/qt/ecoin.qrc
  289. FORMS += \
  290. src/qt/forms/coincontroldialog.ui \
  291. src/qt/forms/sendcoinsdialog.ui \
  292. src/qt/forms/addressbookpage.ui \
  293. src/qt/forms/signverifymessagedialog.ui \
  294. src/qt/forms/aboutdialog.ui \
  295. src/qt/forms/editaddressdialog.ui \
  296. src/qt/forms/transactiondescdialog.ui \
  297. src/qt/forms/overviewpage.ui \
  298. src/qt/forms/sendcoinsentry.ui \
  299. src/qt/forms/askpassphrasedialog.ui \
  300. src/qt/forms/rpcconsole.ui \
  301. src/qt/forms/optionsdialog.ui
  302. contains(USE_QRCODE, 1) {
  303. HEADERS += src/qt/qrcodedialog.h
  304. SOURCES += src/qt/qrcodedialog.cpp
  305. FORMS += src/qt/forms/qrcodedialog.ui
  306. }
  307. CODECFORTR = UTF-8
  308. # for lrelease/lupdate
  309. # also add new translations to src/qt/ecoin.qrc under translations/
  310. TRANSLATIONS = $$files(src/qt/locale/ecoin_*.ts)
  311. isEmpty(QMAKE_LRELEASE) {
  312. win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
  313. else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
  314. }
  315. isEmpty(QM_DIR):QM_DIR = $$PWD/src/qt/locale
  316. # automatically build translations, so they can be included in resource file
  317. TSQM.name = lrelease ${QMAKE_FILE_IN}
  318. TSQM.input = TRANSLATIONS
  319. TSQM.output = $$QM_DIR/${QMAKE_FILE_BASE}.qm
  320. TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
  321. TSQM.CONFIG = no_link
  322. QMAKE_EXTRA_COMPILERS += TSQM
  323. # "Other files" to show in Qt Creator
  324. OTHER_FILES += \
  325. doc/*.rst doc/*.txt doc/README README.md res/ecoin-qt.rc
  326. # platform specific defaults, if not overridden on command line
  327. isEmpty(BOOST_LIB_SUFFIX) {
  328. macx:BOOST_LIB_SUFFIX = -mt
  329. windows:BOOST_LIB_SUFFIX = -mgw44-mt-1_53
  330. }
  331. isEmpty(BOOST_THREAD_LIB_SUFFIX) {
  332. BOOST_THREAD_LIB_SUFFIX = $$BOOST_LIB_SUFFIX
  333. }
  334. isEmpty(BDB_LIB_PATH) {
  335. macx:BDB_LIB_PATH = /opt/local/lib/db48
  336. }
  337. isEmpty(BDB_LIB_SUFFIX) {
  338. macx:BDB_LIB_SUFFIX = -4.8
  339. }
  340. isEmpty(BDB_INCLUDE_PATH) {
  341. macx:BDB_INCLUDE_PATH = /opt/local/include/db48
  342. }
  343. isEmpty(BOOST_LIB_PATH) {
  344. macx:BOOST_LIB_PATH = /opt/local/lib
  345. }
  346. isEmpty(BOOST_INCLUDE_PATH) {
  347. macx:BOOST_INCLUDE_PATH = /opt/local/include
  348. }
  349. windows:DEFINES += WIN32
  350. windows:RC_FILE = src/qt/res/ecoin-qt.rc
  351. windows:!contains(MINGW_THREAD_BUGFIX, 0) {
  352. # At least qmake's win32-g++-cross profile is missing the -lmingwthrd
  353. # thread-safety flag. GCC has -mthreads to enable this, but it doesn't
  354. # work with static linking. -lmingwthrd must come BEFORE -lmingw, so
  355. # it is prepended to QMAKE_LIBS_QT_ENTRY.
  356. # It can be turned off with MINGW_THREAD_BUGFIX=0, just in case it causes
  357. # any problems on some untested qmake profile now or in the future.
  358. DEFINES += _MT BOOST_THREAD_PROVIDES_GENERIC_SHARED_MUTEX_ON_WIN
  359. QMAKE_LIBS_QT_ENTRY = -lmingwthrd $$QMAKE_LIBS_QT_ENTRY
  360. }
  361. !windows:!macx {
  362. DEFINES += LINUX
  363. LIBS += -lrt
  364. }
  365. macx:HEADERS += src/qt/macdockiconhandler.h
  366. macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm
  367. macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit
  368. macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0
  369. macx:ICON = src/qt/res/icons/ecoin.icns
  370. macx:TARGET = "Ecoin-Qt"
  371. macx:QMAKE_CFLAGS_THREAD += -pthread
  372. macx:QMAKE_LFLAGS_THREAD += -pthread
  373. macx:QMAKE_CXXFLAGS_THREAD += -pthread
  374. # Set libraries and includes at end, to use platform-defined defaults if not overridden
  375. INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH $$QRENCODE_INCLUDE_PATH
  376. LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,) $$join(QRENCODE_LIB_PATH,,-L,)
  377. LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
  378. # -lgdi32 has to happen after -lcrypto (see #681)
  379. windows:LIBS += -lws2_32 -lshlwapi -lmswsock -lole32 -loleaut32 -luuid -lgdi32
  380. LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_THREAD_LIB_SUFFIX
  381. windows:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
  382. contains(RELEASE, 1) {
  383. !windows:!macx {
  384. # Linux: turn dynamic linking back on for c/c++ runtime libraries
  385. LIBS += -Wl,-Bdynamic
  386. }
  387. }
  388. system($$QMAKE_LRELEASE -silent $$_PRO_FILE_)